Приложение из урока

Код календаря:

//Для кварталов
QuartersMap:  
MAPPING LOAD   
rowno() as Month,  
'Q' & Ceil (rowno()/3) as Quarter  
AUTOGENERATE (12);  


// Календарь
Temp:  
Load  
min([Дата создания]) as minDate, // указываем поле, откуда берется дата
max([Дата создания]) as maxDate  // указываем поле, откуда берется дата
Resident [Сделки Демо];  // Указываем таблицу, из которой берется дата
      
Let varMinDate = Num(Peek('minDate', 0, 'Temp'));  
Let varMaxDate = Num(Peek('maxDate', 0, 'Temp'));  
DROP Table Temp;  
      
TempCalendar:
LOAD  
$(varMinDate) + Iterno()-1 As Num,  
Date($(varMinDate) + IterNo() - 1) as TempDate  
AutoGenerate 1 While $(varMinDate) + IterNo() -1 <= $(varMaxDate);  
      
[Календарь]:  // Наша таблица с датами

Load  
  date(TempDate, 'DD.MM.YY') AS [Дата создания], // Это поле надо назвать так, как называется поле с датой в таблице, для которой считается календарь  
  Week(weekstart(TempDate)) & '-' & WeekYear(TempDate) as Неделя,  
  Year(TempDate) As [Год],  
  date(MonthStart(TempDate),'MMM-YY') As [Месяц],  
  ApplyMap('QuartersMap', month(TempDate), Null())&' - '& year(TempDate) as [Квартал] 
  
Resident TempCalendar 
Order By TempDate ASC; 

Drop Table TempCalendar; // Табло TempCalendar удаляется